***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 15, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt MMSZ5225B A K 
.param
+vc0 = 8.596e-13	 vc1 = 2.683e-7 	 vc2 = 1.700e0		 vc3 = 6.191e-6		 vc4 = 7.570e0
+tc1 = 3.551e-3		 tc2 = 8.521e-3		 tc3 = 4.291e-3		 tc4 = 3.701e-4	  
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1.739e-14	   n = 1.111		  rs = 5.306e-1
+ibv = 3e-4		 nbv = 1.0		  bv = 3
+ikf = 2.575e-1
***** capacitance parameter *****
+cjo = 2.112e-10	   m = 3.476e-1		  vj = 8.319e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.1		 xti = 3
+trs1 = 1.325e-3	trs2 = 5.925e-6
+tbv1 = -0.9182e-3	tbv2 = 7.456e-8		tikf = 1e-2
.ends MMSZ5225B
*$
